update and fix `packages.out-of-your-element

packages/ooye/package.nix

@@ -0,0 +1,53 @@
+{
+  lib,
+  fetchFromGitea,
+  makeWrapper,
+  nodejs_24,
+  buildNpmPackage,
+}:
+let
+  nodejs = nodejs_24;
+in
+buildNpmPackage {
+  pname = "delete-your-element";
+  version = "3.3-unstable-2026-01-21";
+  src = fetchFromGitea {
+    domain = "git.pvv.ntnu.no";
+    owner = "Drift";
+    repo = "delete-your-element";
+    rev = "d8fdb27feefa07ede43c24e6d17c2c111cf1dde1";
+    hash = "sha256-C2J8N8q2bcNAd4rVD4hONkU0x4iIS2b3MevTgs09/iM=";
+  };
+
+  inherit nodejs;
+
+  patches = [ ./fix-lockfile.patch ];
+
+  npmDepsHash = "sha256-tiGXr86x9QNAwhZcxSOox6sP9allyz9QSH3XOZOb3z8=";
+  dontNpmBuild = true;
+  makeCacheWritable = true;
+
+  nativeBuildInputs = [ makeWrapper ];
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out/share
+    cp -a . $out/share/ooye
+    makeWrapper ${nodejs}/bin/node $out/bin/matrix-ooye --add-flags $out/share/ooye/start.js
+    makeWrapper ${nodejs}/bin/node $out/bin/matrix-ooye-addbot --add-flags $out/share/ooye/addbot.js
+
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    description = "Matrix-Discord bridge with modern features.";
+    homepage = "https://gitdab.com/cadence/out-of-your-element";
+    longDescription = ''
+      Modern Matrix-to-Discord appservice bridge, created by @cadence:cadence.moe.
+    '';
+    license = licenses.gpl3;
+    # maintainers = with maintainers; [ RorySys ];
+    mainProgram = "matrix-ooye";
+  };
+}