nixos-config/hosts/worf/home.nix

{ pkgs
, lib
, inputs
, config
, ...
}: {
  imports = [
    ./../../home/base.nix
    ./../../home/alacritty.nix
  ];

  home.packages = with pkgs; [
    # alacritty
    emacs
    iterm2
    spotify
    ripes
    prismlauncher

    bat
    bottom
    cocoapods
    gnutar
    ncdu
    neofetch
    nix-index
    nodejs
    tldr
    eza
    zellij

    pandoc
    texlive.combined.scheme-full

    (python311.withPackages (ps: with ps; [
      pygments

      jupyter
      numpy
      scipy

      pwntools
      pycryptodome
      requests
    ]))
  ];

  programs.zsh = {
    shellAliases."rebuild" = "darwin-rebuild switch --flake /Users/felixalb/nix";
    prezto.pmodules = [ "ssh" ];
  };

  # Ctrl+y + ,
  programs.neovim.plugins = with pkgs.vimPlugins; [ coc-emmet emmet-vim ];

  # Copy Applications to ~/Applications to allow them to be launched from Spotlight
  disabledModules = [ "targets/darwin/linkapps.nix" ];
  home.activation = lib.mkIf pkgs.stdenv.isDarwin {
    copyApplications =
      let
        apps = pkgs.buildEnv {
          name = "home-manager-applications";
          paths = config.home.packages;
          pathsToLink = "/Applications";
        };
      in
      lib.hm.dag.entryAfter [ "writeBoundary" ] ''
        baseDir="$HOME/Applications/Home Manager Apps"
        if [ -d "$baseDir" ]; then
          rm -rf "$baseDir"
        fi
        mkdir -p "$baseDir"
        for appFile in ${apps}/Applications/*; do
          target="$baseDir/$(basename "$appFile")"
          $DRY_RUN_CMD cp ''${VERBOSE_ARG:+-v} -fHRL "$appFile" "$baseDir"
          $DRY_RUN_CMD chmod ''${VERBOSE_ARG:+-v} -R +w "$target"
        done
      '';
  };

  home.stateVersion = "23.05";
}